JsonGeneratorExample

Json庫

// Copyright Benoit Blanchon 2014-2016
// MIT License
//
// Arduino JSON library
// https://github.com/bblanchon/ArduinoJson
// If you like this project, please add a star!

#include <ArduinoJson.h>

void setup() {
  Serial.begin(9600);
  while (!Serial) {
    // wait serial port initialization
  }

  // Memory pool for JSON object tree. -- 为JSON对象树创建内存池
  //
  // Inside the brackets, 200 is the size of the pool in bytes. -- 200字节为内存是大小
  // If the JSON object is more complex, you need to increase that value. -- 如果JSON对象过于复杂，你需要更改这个内存大小
  StaticJsonBuffer<200> jsonBuffer;

  // StaticJsonBuffer allocates memory on the stack, it can be
  // replaced by DynamicJsonBuffer which allocates in the heap.
  //  -- StaticJsonBuffer 在栈上分配内存，它可以被在堆上分配内存的DynamicJsonBuffer所代替
  // It's simpler but less efficient. -- DynamicJsonBuffer 简单但效率低
  //
  // DynamicJsonBuffer  jsonBuffer;

  // Create the root of the object tree. -- 创建对象树的根
  //
  // It's a reference to the JsonObject, the actual bytes are inside the
  // JsonBuffer with all the other nodes of the object tree.
  //  -- 这是对JsonObject参考，实际字节是JSONBuffer内的对象树的所有其他节点
  // Memory is freed when jsonBuffer goes out of scope. -- jsonBuffer超出范围时内存已经被释放了
  JsonObject& root = jsonBuffer.createObject();

  // Add values in the object -- 在对象中添加值
  //
  // Most of the time, you can rely on the implicit casts.-- 大多数情况下，你可以依靠隐式转换
  // In other case, you can do root.set<long>("time", 1351824120);-- 其他情况下，你可以这样写 root.set<long>("time", 1351824120);
  root["sensor"] = "gps";
  root["time"] = 1351824120;

  // Add a nested array.  --  添加一个嵌套的数组
  //
  // It's also possible to create the array separately and add it to the
  // JsonObject but it's less efficient.-- 它也可以分别创建数组并把它添加到的JSONObject但它的效率较低
  JsonArray& data = root.createNestedArray("data");
  data.add(double_with_n_digits(48.756080, 6));
  data.add(double_with_n_digits(2.302038, 6));

  root.printTo(Serial);
  // This prints:
  // {"sensor":"gps","time":1351824120,"data":[48.756080,2.302038]}

  Serial.println();

  root.prettyPrintTo(Serial);
  // This prints:
  // {
  //   "sensor": "gps",
  //   "time": 1351824120,
  //   "data": [
  //     48.756080,
  //     2.302038
  //   ]
  // }
}

void loop() {
  // not used in this example
}

---

返回Arduino庫菜單

返回首頁

更多建議和問題歡迎反饋至 YFRobot論壇