查看温湿度传感器 - DHT22的源代码


[[Image:DHT22温湿度传感器模块.jpg|400px|thumb|DHT22温湿度传感器模块]]


=== 产品简介 ===
<br>
温湿度传感器 - DHT22模块是采用DHT22 数字温湿度传感器元件设计的模块，可用来对环境温度和湿度进行检测。总线方式与arduino 进行数据传输，单线制串行接口，使系统集成变得简易快捷。超小的体积、极低的功耗，信号传输距离可达20 米以上，使其成为各类应用甚至最为苛刻的应用场合的最佳选则。

传感器包括一个电阻式感湿元件和一个NTC测温元件，并与一个高性能8位单片机相连接。因此该产品具有品质卓越、超快响应、抗干扰能力强、性价比极高等优点。每个DHT22传感器都在极为精确的湿度校验室中进行校准。校准系数以程序的形式储存在OTP内存中，传感器内部在检测信号的处理过程中要调用这些校准系数。产品为4 针单排引脚封装。连接方便，特殊封装形式可根据用户需求而提供。

DHT22是数字温湿度传感器并且含有已校准数字信号输出。它应用专用的数字模块采集技术和温湿度传感技术，确保产品具有极高的可靠性与卓越的长期稳定性。相对[[温湿度传感器 - DHT11|DHT11]],DHT22精确度很高，可以替代昂贵的进口SHT10温湿度传感器。

DHT22特点总结：超低能耗、传输距离远、全部自动化校准、采用电容式湿敏元件、完全互换、标准数字单总线输出、卓越的长期稳定性、采用高精度测温元件。



=== 规格参数 ===
<br>
*供电电压：DC3～5V，建议5V
*测量温度范围：-40℃ ～ 80℃
*测量湿度范围：0%RH ～ 99.9%RH
*温度测量精度：±1℃
*湿度测量精度：±2%RH
*温湿灵敏度： 0.1℃ / 0.1%RH 
*响应时间：温度 <5s /湿度 <10s
*采样周期：2s
*输出形式：数字输出 
*安装孔径：3MM
*模块尺寸：36*21*9.5MM （长*宽*高）
*孔间距：15MM
*模块重量：7.9g



=== 主要应用 ===
<br>
暖通空调、除湿器、测试及检测设备、消费品、汽车、自动控制、数据记录器、家电、湿度调节器、医疗、气象站、及其他相关湿度检测控制等。


=== 引脚说明 ===
<br>
*1. G -- Gnd(地)
*2. V -- Vcc(电源+5V)
*3. S -- Sign(信号)



=== 应用示例 ===
<br>
:'''电路连接示意图'''
<br>
::'''DHT22模块'''的 G、V、S分别连接 '''Arduino UNO'''的GND、VCC(+5V)、A1引脚。

 
<!--[[Image: LED模块.jpg|400px|center|LED模块接线图]]-->



:'''示例代码'''

<pre>
//
//    FILE: dht22_test.ino
//  AUTHOR: Rob Tillaart
// VERSION: 0.1.03
// PURPOSE: DHT library test sketch for DHT22 && Arduino
//     URL:
// HISTORY:
// 0.1.03 extended stats for all errors
// 0.1.02 added counters for error-regression testing.
// 0.1.01
// 0.1.00 initial version
//
// Released to the public domain
//

#include <dht.h>

dht DHT;

#define DHT22_PIN A1

struct
{
    uint32_t total;
    uint32_t ok;
    uint32_t crc_error;
    uint32_t time_out;
    uint32_t connect;
    uint32_t ack_l;
    uint32_t ack_h;
    uint32_t unknown;
} stat = { 0,0,0,0,0,0,0,0};

void setup()
{
    Serial.begin(9600);
    Serial.println("dht22_test.ino");
    Serial.print("LIBRARY VERSION: ");
    Serial.println(DHT_LIB_VERSION);
    Serial.println();
    Serial.println("Type,\tstatus,\tHumidity (%),\tTemperature (C)\tTime (us)");
}

void loop()
{
    // READ DATA
    Serial.print("DHT22, \t");

    uint32_t start = micros();
    int chk = DHT.read22(DHT22_PIN);
    uint32_t stop = micros();

    stat.total++;
    switch (chk)
    {
    case DHTLIB_OK:
        stat.ok++;
        Serial.print("OK,\t");
        break;
    case DHTLIB_ERROR_CHECKSUM:
        stat.crc_error++;
        Serial.print("Checksum error,\t");
        break;
    case DHTLIB_ERROR_TIMEOUT:
        stat.time_out++;
        Serial.print("Time out error,\t");
        break;
    case DHTLIB_ERROR_CONNECT:
        stat.connect++;
        Serial.print("Connect error,\t");
        break;
    case DHTLIB_ERROR_ACK_L:
        stat.ack_l++;
        Serial.print("Ack Low error,\t");
        break;
    case DHTLIB_ERROR_ACK_H:
        stat.ack_h++;
        Serial.print("Ack High error,\t");
        break;
    default:
        stat.unknown++;
        Serial.print("Unknown error,\t");
        break;
    }
    // DISPLAY DATA
    Serial.print(DHT.humidity, 1);
    Serial.print(",\t");
    Serial.print(DHT.temperature, 1);
    Serial.print(",\t");
    Serial.print(stop - start);
    Serial.println();

    if (stat.total % 20 == 0)
    {
        Serial.println("\nTOT\tOK\tCRC\tTO\tUNK");
        Serial.print(stat.total);
        Serial.print("\t");
        Serial.print(stat.ok);
        Serial.print("\t");
        Serial.print(stat.crc_error);
        Serial.print("\t");
        Serial.print(stat.time_out);
        Serial.print("\t");
        Serial.print(stat.connect);
        Serial.print("\t");
        Serial.print(stat.ack_l);
        Serial.print("\t");
        Serial.print(stat.ack_h);
        Serial.print("\t");
        Serial.print(stat.unknown);
        Serial.println("\n");
    }
    delay(2000);
}
//
// END OF FILE
//
</pre>

程序下载地址：[http://pan.baidu.com/s/1qWFZ8lu dit22_test]


:'''串口监视结果'''
<br>
[[Image:DHT22温湿度传感器串口监视.png|center|DHT22串口监视结果]]





===参考资料===
<br>
*[http://pan.baidu.com/s/1o61Q86A DHT22数据手册]
*DHT22库文件下载：[http://pan.baidu.com/s/1dD2iBW9 DHTlib]


----


[[首页 | 返回首页]]

更多建议和问题欢迎反馈至 [http://www.yfrobot.com YFRobot论坛]

购买方式:[http://yfrobot.taobao.com/ YFRobot 电子工作室]