ShiftOut()

描述

一次移位一位數據一位。 從最多（即最左邊）或最少（最右邊）有效位開始。 每個位依次寫入數據引腳，之後時鐘引腳被脈衝（高電平，然後為低電平）以指示該位可用。

注意：如果您正在與上升沿時鐘的器件進行接口，那麼在調用shiftOut()之前，需要確保時鐘引腳為低電平。 調用digitalWrite(clockPin，LOW)。

這是一個軟件實現; 另見SPI庫，它提供了一個更快的硬件實現，但僅適用於特定的引腳。

語法

shiftOut(dataPin, clockPin, bitOrder, value)

參數

• dataPin：要在其上輸出每個位的引腳（int）
• clockPin：一旦dataPin被設置為正確的值（int），該引腳就會切換
• bitOrder：哪個順序移出位？ MSBFIRST或LSBFIRST。（最高有效位優先，或最低有效位優先）
• value: 將數據移出。（位元組）

返回

None

注意

必須通過調用pinMode()將dataPin和clockPin配置為輸出。

shiftOut當前被寫入輸出1個位元組（8位），因此需要兩步操作來輸出大於255的值。

// Do this for MSBFIRST serial
int data = 500;
// shift out highbyte
shiftOut(dataPin, clock, MSBFIRST, (data >> 8));  
// shift out lowbyte
shiftOut(dataPin, clock, MSBFIRST, data);

// Or do this for LSBFIRST serial
data = 500;
// shift out lowbyte
shiftOut(dataPin, clock, LSBFIRST, data);  
// shift out highbyte 
shiftOut(dataPin, clock, LSBFIRST, (data >> 8)); 

示例

有關相關電路，請參閱有關控制74HC595移位寄存器的教程。

//**************************************************************//
//  Name    : shiftOutCode, Hello World                         //
//  Author  : Carlyn Maw,Tom Igoe                               //
//  Date    : 25 Oct, 2006                                      //
//  Version : 1.0                                               //
//  Notes   : Code for using a 74HC595 Shift Register           //
//          : to count from 0 to 255                            //
//****************************************************************

//Pin connected to ST_CP of 74HC595
int latchPin = 8;
//Pin connected to SH_CP of 74HC595
int clockPin = 12;
////Pin connected to DS of 74HC595
int dataPin = 11;

void setup() {
  //set pins to output because they are addressed in the main loop
  pinMode(latchPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  pinMode(dataPin, OUTPUT);
}

void loop() {
  //count up routine
  for (int j = 0; j < 256; j++) {
    //ground latchPin and hold low for as long as you are transmitting
    digitalWrite(latchPin, LOW);
    shiftOut(dataPin, clockPin, LSBFIRST, j);   
    //return the latch pin high to signal chip that it 
    //no longer needs to listen for information
    digitalWrite(latchPin, HIGH);
    delay(1000);
  }
} 

擴展閱讀

- shiftIn()

---

返回Arduino語法參考列表

更多建議和問題歡迎反饋至 YFRobot論壇